Radix Conversion

Radix Conversion(基数変換)

Introduction

10進数⇔n進数(2≦n≦16)の相互変換をサポートした、基数変換プログラムです。※符号(マイナス値)と少数は扱えません。

<注意!>
プログラムの実行前に、必ず DEFM 15(要120step) してください。

 
スクリーンショット
RUN DEG
<実行画面1>基数(Base Number)を入力します。※2≦n≦16
RUN DEG
<実行画面2>10進数(Decimal Number)を入力します。
RUN DEG STOP
<実行画面3>10進数の15を2進数に変換した結果(DEC2BIN)


※DEC2n-adic(プログラムエリアP0)実行画面

 

Contents of the Program

サブルーチン概要
[プログラムエリアP0] DEC2n-adic/10進数整数をn進数(2≦n≦16)文字列に変換します。
[プログラムエリアP1] n-adic2DEC/n進数(2≦n≦16)文字列を10進数整数に変換します。

<注意!>
プログラムの実行前に、必ず DEFM 15(要120step) してください。

 
◆基数変換の使い方
[プログラムエリアP0] DEC2n-adic
<数値>
変換する10進数の整数を指定します。n進数表示の関係で、指定できる数値はn^30までです。
<解説>
数値にn^30を超える値を指定すると、エラーが返されます。


[プログラムエリアP1] n-adic2DEC
<数値>
変換するn進数を文字列として指定します。数値に指定できる文字数は、入力の関係で30桁までです(文字列は大文字のみ)。
<解説>
数値にn進数以外の値を指定すると、エラーが返されます。

 
◆2進数・8進数・10進数・16進数対応表
2進数 8進数 10進数 16進数
10
11
100
101
110
111
1000 10
1001 11
1010 12 10
1011 13 11
1100 14 12
1101 15 13
1110 16 14
1111 17 15
 

Technical Documentation

Program List for PB-100
RadixConversionのプログラムリスト
※上記プログラムリストは、マウスの右クリックで“名前を付けて画像を保存”すると、原寸大(570×236pixel)で見ることが出来ます。
Program List for PB-SIM

[P0]
10 PRINT "DEC2n-adic":GOSUB #9
20 INPUT "DEC",D:IF D>=N^30;PRINT "ERR":GOTO 20
30 M=INT D:$=""
40 A=INT (M/N):$=Z$(M-A*N)+$:M=A:IF M<>0 THEN 40
50 PRINT $:GOTO 20

[P1]
10 PRINT "n-adic2DEC":GOSUB #9
20 INPUT "DIGIT",$:A=0
30 FOR I=1 TO LEN($)
40 FOR J=0 TO N-1
50 IF MID(I,1)=Z$(J) THEN 70
60 NEXT J:PRINT "ERR:";$:GOTO 20
70 A=A*N+J:NEXT I:PRINT A:GOTO 20

[P9]
10 VAC:$="0123456789ABCDEF"
20 FOR I=1 TO 16:Z$(I-1)=MID(I,1):NEXT I
30 INPUT "BASE(n)",B:N=INT B:IF N*(N-1)<>0;IF N<=16;RETURN
40 GOTO 30
50 "Radix Conv. "
60 " 2013/02/16"
70 " AUTHOR:HIE"

 
変数表
変数 説明
$,Z$(0)〜Z$(15) n進数文字列データ
A,M,N 演算&制御用
基数
10進数整数
I,J ループ(汎用)
 
プログラムマップ
[P0] DEC2n-adic/メインルーチン(108step)
行番号 説明
10 タイトル表示、初期設定
20 10進数整数入力、エラー処理
30〜40 n進数文字列変換処理
50 結果表示処理
 
[P1] n-adic2DEC/メインルーチン(116step)
行番号 説明
10 タイトル表示、初期設定
20 n進数文字列入力処理
30〜70 10進数整数変換、エラー、結果表示処理
 
[P9] サブルーチン#1(97step ※注釈行含めず)
行番号 説明
10 初期設定
20 n進数文字列生成処理
30〜40 基数入力処理
50〜70 注釈行※この行以降は無視

 

COMMENT







   

PAGE TOP