脳トレ(Pocket Brain Training!)

脳トレ(Pocket Brain Training!)

Introduction

脳トレシリーズ第一弾は、記憶力の限界に挑戦するゲームです。
増設RAM(OR-1/E)なしのPB-110シリーズで遊べます。


※このゲームはPB-110シリーズ専用ですが、[チェックポイント]を参照にプログラムリストを変更すれば、PB-100シリーズで動作させることができます。
 
スクリーンショット
RUN DEG STOP
L v 1 A N S 1
<実行画面1>Lv1は配列パターン1個記憶して、それを答えればOK!
RUN DEG STOP
M e m o r i z e i t !
<実行画面2>メモライズ開始。表示される配列パターンを順に憶えよう!
RUN DEG STOP
1 : o ( ' - ' o )
<実行画面3>1番目はこれ! レベルが上がるごとに数が増えて難しくなるよ。

 

Game Story and System

ゲーム内容
画面上に順番に表示される最大24個の顔文字の配列パターンを記憶し、思い出せる限りの解答を入力するゲームです。
出題される配列パターンの数(=記憶しなければいけない数)は、レベルに応じて増えていきます(最小:レベル1→1個/最大:レベル24→24個)。
そのレベルで出題された配列パターンを全て解答することができればクリアとなりますが、解答を間違えた段階で、即ゲームオーバーです。
なお、出題される配列パターンの再表示は制限回数なく可能なので、メモライズが不安な方は、“Again(Y/N)?”と訊かれたときに、“Y”と入力してください。


※このゲームはPB-110シリーズ専用ですが、[チェックポイント]を参照にプログラムリストを変更すれば、PB-100シリーズで動作させることができます。
 

Characters

登場キャラクタ
キャラクタパターン 説明
o ( ' - ' o ) 左向き
BEEP 0(低音)
( o ' - ' ) o 右向き
BEEP 1(高音)
 

Operation Guide

基本操作説明
4
顔文字の左向きを入力
6
顔文字の右向きを入力
EXE
画面送り、決定
 

Program Execution

プログラムの入力
脳トレ(Pocket Brain Training!)for PB-110のプログラムを入力する前に、下記の操作を実行してください。
実行後、プログラムリストをよく見て、間違いのないように入力してください。

 
MODE 1
プログラム入力モード(WRT)に切り替え
Shift 0
プログラムエリア[P0]に切り替え
CLEAR A EXE
メモリ内に書き込まれている全てのプログラムを消去
DEFM 0 EXE
メモリ(変数)を設定
 
プログラムの実行
脳トレ(Pocket Brain Training!)for PB-110のプログラムの入力後、下記の操作を実行するとゲームスタートです。
 
MODE 0
プログラム実行モード(RUN)に切り替え
Shift 0
指定されたプログラムエリア[P0]のプログラムを実行
 

Technical Documentation

Program List for PB-110
脳トレのプログラムリスト
※上記プログラムリストは、マウスの右クリックで“名前を付けて画像を保存”すると、原寸大(570×353pixel)で見ることが出来ます。
Program List for PB-SIM ※PB-110用オリジナル版(BEEPあり)

[P0]
1 A$="¥CI('-')¥CI":B$="o('-')o":C$="o('-'o)":D$="(o'-')o":L=1:S=0
2 $="121234":G=0:T=9:PRINT "GENERATE ";:FOR I=1 TO L
3 $=$+MID(2+INT(RAN#*2+2),1):NEXT I:PRINT "OK!"
4 PRINT CSR 1;L;"¥RAANS";L;CSR 0;"Lv","Memorize it!"
5 FOR I=1 TO L:GOSUB #1:PRINT CSR 0;I;":";A$(F);:BEEP F-2:NEXT I
6 GOSUB #2: INPUT "Again(Y/N)",R$:IF R$="Y" THEN 5
7 PRINT "Let's ANS!":FOR I=1 TO 6
8 PRINT CSR 2;A$;CSR 9;MID(I,1);CSR 2;B$;:IF I>=3;T=1
9 GOSUB #2:NEXT I:FOR I=1 TO L:GOSUB #1:PRINT :PRINT CSR 0;I;":";
10 O$=KEY:IF O$="" THEN 10
11 IF O$>="4";IF O$<="6";IF VAL(O$)/2=F THEN 13
12 PRINT :PRINT "GAME OVER",S;"p":END
13 PRINT A$(F);:BEEP F-2:G=G+1:S=S+G*L*10
14 NEXT I:PRINT :PRINT "GREAT!","BONUS";L*100:S=S+L*100
15 L=L+1:IF L>=24;L=24
16 GOTO 2

[P1]
1 E$=MID(6+I,1):F=VAL(E$):RETURN

[P2]
1 FOR J=0 TO T:NEXT J:PRINT :RETURN

[P9]
1 REM "PB-Training!v1.0"
2 REM " 2013/01/01"
3 REM " AUTHOR:HIE"

 
Program List for PB-SIM ※PB-100用改良版(BEEPなし)

[P0]
1 A$="¥CI('-')¥CI":B$="o('-')o":C$="o('-'o)":D$="(o'-')o":L=1:S=0
2 $="121234":G=0:T=9:PRINT "GENERATE ";:FOR I=1 TO L
3 $=$+MID(2+INT(RAN#*2+2),1):NEXT I:PRINT "OK!"
4 PRINT CSR 1;L;"¥RAANS";L;CSR 0;"Lv","Memorize it!"
5 FOR I=1 TO L:GOSUB #1:PRINT CSR 0;I;":";A$(F);:NEXT I
6 GOSUB #2: INPUT "Again(Y/N)",R$:IF R$="Y" THEN 5
7 PRINT "Let's ANS!":FOR I=1 TO 6
8 PRINT CSR 2;A$;CSR 9;MID(I,1);CSR 2;B$;:IF I>=3;T=1
9 GOSUB #2:NEXT I:FOR I=1 TO L:GOSUB #1:PRINT :PRINT CSR 0;I;":";
10 O$=KEY:IF O$="" THEN 10
11 IF O$>="4";IF O$<="6";IF VAL(O$)/2=F THEN 13
12 PRINT :PRINT "GAME OVER",S;"p":END
13 PRINT A$(F);:G=G+1:S=S+G*L*10
14 NEXT I:PRINT :PRINT "GREAT!","BONUS";L*100:S=S+L*100
15 L=L+1:IF L>=24;L=24
16 GOTO 2

[P1]
1 E$=MID(6+I,1):F=VAL(E$):RETURN

[P2]
1 FOR J=0 TO T:NEXT J:PRINT :RETURN

[P9]
1 REM "PB-Training!v1.1"
2 REM " 2013/01/01"
3 REM " AUTHOR:HIE"

 
チェックポイント
このプログラムはPB-110シリーズ専用ですが、プログラムリストを以下のように変更すれば、PB-100シリーズで動作させることができます。
[P0]
行番号 説明
5行 :BEEP F-2を削除
13行 :BEEP F-2を削除
変数表
変数 説明
出題データ作成用
A$,B$,C$,D$ 顔文字データ…A$(0)〜A$(3)
E$ 出題データ取得用(文字列)
出題データ取得用(数値化)
I,J ループ用(汎用)
レベル
キー入力用
R$ メモライズリプレイ用
スコア
ウェイト
プログラムマップ
[P0] メインルーチン(506step)
行番号 説明
初期設定
2〜3 出題データ作成
4〜6 メモライズモード(レベル表示、出題データ表示等)
7〜10 アンサーモード(お邪魔演出、キー入力待ち等)
11 キー入力(解答)判定
12 ゲームオーバー処理
13 正解処理
14〜16 レベルクリア処理
[P1] サブルーチン#1(22step)
行番号 説明
出題データ取得
[P2] サブルーチン#2(16step)
行番号 説明
表示ウェイト処理
[P9] サブルーチン#3
行番号 説明
1〜3 注釈行※この行以降は無視
 
特殊キャラクタ一覧
プログラムリスト内で使用している特殊キャラクタのエスケープシーケンスは下記の通りです。
Bernie様のPocket BASIC Simulator.でプレイする際は、お手数ですが手動で変換してください。
キャラクタパターン エスケープシーケンス
¥CI
¥RA

COMMENT







   

PAGE TOP