PB-RACER

PB-RACER(ピービー・レーサー)

Introduction

ライバルカーを避けながら、制限時間内にどこまで走行距離を延ばせるかを競うゲームです。
増設RAM(OR-1/E)なしのPB-100シリーズで遊べます。

 
スクリーンショット
RUN RAD STOP
[ _ G O ! _ ] N
<実行画面1>プ・プ・プ、プーン♪(スタートです!)
RUN RAD
[ _ - _ ] L
<実行画面2>前方にライバルカーを発見!
RUN RAD
[ _ T - _ ] H
<実行画面3>クラッシュしないように疾走!

 

Game Story and System

プロローグ
カーレースの最高峰であるPBレース。その頂点に君臨する者を「チャンピオンレーサー」という。
あなたは駆け出しのPBレーサー。ライバルカーを蹴散らし、勝利の栄冠を手にすることはできるのか!
今、レーサー達の魂がぶつかり合う、熱い戦いの幕が開く!
◆RACE#1:ストレートバトル
今作は、走行ラインが3車線の直線(ストレート)コースが舞台です。
ライバルカーとクラッシュしないように、走行ラインを変更しながら疾走してください。
クラッシュすると、制限時間が-5されてしまいます。

 

Characters

登場キャラクタ
キャラクタパターン 説明
ライバルカー(遠)
ライバルカー(中)
T ライバルカー(近)
※ライバルカーは遠方より、 T の順でこちら(手前)に迫ってきます。
 

Operation Guide

基本操作説明
4
走行ラインをDEGに変更(移動)
5
走行ラインをRADに変更(移動)
6
走行ラインをGRAに変更(移動)
Z
ギア:HIGH
X
ギア:LOW
EXE
画面送り、決定
 
◆走行ラインについて
PB-RACERは、コックピット視点(ドライバーズビュー)でゲームが進行するため、ゲーム画面上に自車のキャラクタは表示されません。
自車が現在どの走行ライン上にいるのかは、MODE表示で確認してください。
RUN DEG
[ _ T - _ ] H
<説明画面1>走行ライン左端/MODE表示[DEG]:対応キー 4
RUN RAD
[ _ - T - _ ] H
<説明画面2>走行ライン中央/MODE表示[RAD]:対応キー 5
RUN GRA
[ _ - T _ ] H
<説明画面3>走行ライン右端/MODE表示[GRA]:対応キー 6

※自車キャラクタ( T )は、画面上に表示させた場合のイメージです。
 

Program Execution

プログラムの入力
PB-RACER for PB-100のプログラムを入力する前に、下記の操作を実行してください。
実行後、プログラムリストをよく見て、間違いのないように入力してください。

 
MODE 1
プログラム入力モード(WRT)に切り替え
Shift 0
プログラムエリア[P0]に切り替え
CLEAR A EXE
メモリ内に書き込まれている全てのプログラムを消去
DEFM 0 EXE
メモリ(変数)を設定
 
プログラムの実行
PB-RACER for PB-100のプログラムの入力後、下記の操作を実行するとゲームスタートです。
 
MODE 0
プログラム実行モード(RUN)に切り替え
Shift 0
指定されたプログラムエリア[P0]のプログラムを実行
 

Technical Documentation

Program List for PB-100
PB-RACERのプログラムリスト
※上記プログラムリストは、マウスの右クリックで“名前を付けて画像を保存”すると、原寸大(570×327pixel)で見ることが出来ます。
Program List for PB-SIM ※オリジナル版(スタートシグナルなし)

[P0]
10 VAC:A$="¥DT":B$="¥TR":C$="¥SQT¥SQ":F$="N":T=59:X=4
20 GOSUB #1:PRINT CSR 3;"GO!"
30 $="  -   - - -   -":D=0:E=0:H=0:V=1:GOSUB #2
40 GOSUB #1:K$=KEY
50 IF K$>="4";IF K$<="6";X=VAL(K$)-1:GOSUB #1:GOTO 80
60 IF K$="Z";IF F$<>"N";IF G=1;F$="H":G=2
70 IF K$="X";IF G<>1;F$="L":G=1
80 IF G<>0;U=U+1*G:IF U>=2 THEN 110
90 T=T-1:IF T<=0 THEN 160
100 GOTO 40
110 V=V+5:D=D+1:E=E+1:IF V>11 THEN 140
120 IF D=2;IF E=2;H=-1
130 S=S+1*G:GOSUB #1:U=0:GOTO 90
140 IF X<>P;IF X<>Q THEN 30
150 PRINT CSR X-1;"(*)";:T=T-5:GOTO 30
160 PRINT :PRINT "GAME OVER!",S;"km"

[P1]
10 MODE X+1:PRINT CSR 0;"[¥CS";CSR 7;"¥CS]";F$;
20 IF V>0;PRINT CSR 2;MID(V,5);
30 IF G<>0;IF P>=3;IF P<=5;PRINT CSR P+H;A$(D);
40 IF G<>0;IF Q>=3;IF Q<=5;PRINT CSR Q+H;A$(E);
50 RETURN

[P2]
10 FOR I=0 TO 1:P(I)=INT (RAN#*5)+2:NEXT I:IF P=Q THEN 10
20 RETURN
30 REM "PB-RACERv1.0"
40 REM " 2012/08/07"
50 REM " AUTHOR:HIE"

 
Program List for PB-SIM ※PB-SIM版(スタートシグナルあり)

[P0]
10 VAC:A$="¥DT":B$="¥TR":C$="¥SQT¥SQ":F$="N":T=59:X=4
20 GOSUB #1:PRINT CSR 3;"12¥CI";
30 FOR I=2 TO 1 STEP -1:GOSUB #2:PRINT CSR 2+I;I+1;CSR 2+I;"¥CI";:NEXT I
40 GOSUB #2:PRINT CSR 3;"GO!";:GOSUB #2
50 $="  -   - - -   -":D=0:E=0:H=0:V=1:GOSUB #3
60 GOSUB #1:K$=KEY
70 IF K$>="4";IF K$<="6";X=VAL(K$)-1:GOSUB #1:GOTO 100
80 IF K$="Z";IF F$<>"N";IF G=1;F$="H":G=2
90 IF K$="X";IF G<>1;F$="L":G=1
100 IF G<>0;U=U+1*G:IF U>=2 THEN 130
110 T=T-1:IF T<=0 THEN 180
120 GOTO 60
130 V=V+5:D=D+1:E=E+1:IF V>11 THEN 160
140 IF D=2;IF E=2;H=-1
150 S=S+1*G:GOSUB #1:U=0:GOTO 110
160 IF X<>P;IF X<>Q THEN 50
170 PRINT CSR X-1;"(*)";:T=T-5:GOTO 50
180 PRINT :PRINT "GAME OVER!",S;"km"

[P1]
10 MODE X+1:PRINT CSR 0;"[¥CS";CSR 7;"¥CS]";F$;
20 IF V>0;PRINT CSR 2;MID(V,5);
30 IF G<>0;IF P>=3;IF P<=5;PRINT CSR P+H;A$(D);
40 IF G<>0;IF Q>=3;IF Q<=5;PRINT CSR Q+H;A$(E);
50 RETURN

[P2]
10 FOR J=0 TO 99:NEXT J:RETURN

[P3]
10 FOR I=0 TO 1:P(I)=INT (RAN#*5)+2:NEXT I:IF P=Q THEN 10
20 RETURN
30 REM "PB-RACERv1.1"
40 REM "  2012/09/09"
50 REM "  AUTHOR:HIE"

 
変数表
変数 説明
コースデータ
A$,B$,C$ 敵車データ…A$(0)〜A$(2)
D,E 敵車車間距離カウンタ
F$ ギアの状態
ギアフラグ
敵車座標補正用
ループ(汎用)
K$ キー入力
P,Q 敵車座標
総走行距離(スコア)
制限時間
自車走行距離カウンタ
コース描画用
自車座標
プログラムマップ
[P0] メインルーチン(388step)
行番号 説明
10 初期設定
20 スタートシグナル処理
30 変数設定
40 画面描画
50〜70 キー入力判定
80 自車走行判定
90〜100 制限時間判定
110〜130 自車&敵車走行処理
140〜150 衝突判定
160 ゲームオーバー処理
[P1] サブルーチン#1(110step)
行番号 説明
10 メイン画面描画
20 コース描画
30〜50 敵車描画
[P2] サブルーチン#2(38step ※注釈行含まず)
行番号 説明
10〜20 敵車配置設定
30〜50 注釈行※この行以降は無視
特殊キャラクタ一覧
プログラムリスト内で使用している特殊キャラクタのエスケープシーケンスは下記の通りです。
Bernie様のPocket BASIC Simulator.でプレイする際は、お手数ですが手動で変換してください。
キャラクタパターン エスケープシーケンス
¥DT
¥TR
¥SQ
_ ¥CS

 

COMMENT







   

PAGE TOP