Inflator

Inflator

Introduction

単純明快! 風船を膨らませて破裂させるゲームです。
増設RAM(OR-1/E)なしのPB-100シリーズで遊べます。


※参考文献等
コナミ FC「ハイパーオリンピック」

 
スクリーンショット
RUN DEG STOP
Ω _ . R E A D Y
<実行画面1>位置について、用意、ドン♪ フライング3回で失格になるよ。
RUN DEG STOP
o _ o 0 . 1 6
<実行画面2>一生懸命空気を送って、風船を膨らませよう!
RUN DEG STOP
o _ * F I N I S H !
<実行画面3>やった〜割れた!! さて、気になるタイムは!?

 

Game Story and System

ゲーム内容
風船を膨らませて、破裂するまでの記録を競うゲームです。
スタートの合図とともに 4 6 のキーを交互に押して(開始は 4 からです)、風船に空気を送ります。
フライング3回で失格となりますので、注意してください。
※風船は、 . (初期段階)→ O (最終段階)へと膨らんで、最後には破裂します。


※参考文献等
コナミ FC「ハイパーオリンピック」

 

Characters

登場キャラクタ
キャラクタパターン 説明
Ω プレイヤー
. 風船(初期段階)
 

Operation Guide

基本操作説明
4
空気入れA
6
空気入れB
EXE
画面送り、決定
 

Program Execution

プログラムの入力
Inflator for PB-100のプログラムを入力する前に、下記の操作を実行してください。
実行後、プログラムリストをよく見て、間違いのないように入力してください。

 
MODE 1
プログラム入力モード(WRT)に切り替え
Shift 0
プログラムエリア[P0]に切り替え
CLEAR A EXE
メモリ内に書き込まれている全てのプログラムを消去
DEFM 0 EXE
メモリ(変数)を設定
 
プログラムの実行
Inflator for PB-100のプログラムの入力後、下記の操作を実行するとゲームスタートです。
◆初回起動時(ファーストブート)
MODE 0
プログラム実行モード(RUN)に切り替え
Shift 9
指定されたプログラムエリア[P9]のプログラムを実行
◆初回起動時以降(ホットスタート)
MODE 0
プログラム実行モード(RUN)に切り替え
Shift 0
指定されたプログラムエリア[P0]のプログラムを実行
 

Technical Documentation

Program List for PB-100
Inflatorのプログラムリスト
※上記プログラムリストは、マウスの右クリックで“名前を付けて画像を保存”すると、原寸大(570×353pixel)で見ることが出来ます。
Program List for PB-SIM

[P0]
1 H=4:P=0:Q=0:S=0:X=0:Y=0
2 PRINT :PRINT "RT";T,"BY ";N$:GOSUB #2:PRINT
3 GOSUB #1:K$=KEY:PRINT CSR 3;S;
4 IF K$<>"";IF H=VAL(K$);H=10-H:X=X+1:IF X>1;X=0:Y=Y+1
5 IF Y>3;Y=0:P=P+1:IF P>3 THEN 7
6 S=S+.01:GOTO 3
7 PRINT CSR 2;C$(P);CSR 4;"FINISH!"
8 PRINT "QT";S;:IF T>S;T=S:PRINT CSR 8;"[NR]":GOTO 10
9 STOP:GOTO 1
10 INPUT "Name",N$:PRINT "  Thanks!":GOTO 1

[P1]
1 PRINT CSR 0;A$(X);"_";C$(P);:RETURN

[P2]
1 Z=1:FOR I=1 TO 2:R=INT(RAN#*7+1)*10:GOSUB #1
2 PRINT CSR 4;MID(Z,5);:FOR J=0 TO 29+R
3 IF KEY<>"" THEN 5
4 NEXT J:Z=Z+5:NEXT I:PRINT CSR 5;"GO!";:GOSUB #3:RETURN
5 PRINT CSR 4;"FLYING!";:GOSUB #3
6 Q=Q+1:IF Q=3;PRINT :PRINT "disqualified":GOTO #0
7 PRINT :GOTO 1

[P3]
1 FOR I=0 TO 99:NEXT I:RETURN

[P9]
1 VAC:A$="¥OM":B$="o":C$=".":D$=B$:E$=A$:F$="O":G$="*"
2 T=16:N$="HIE":$="READY SET ":GOTO #0
3 "Inflator    "
4 "  2013/03/20"
5 "  AUTHOR:HIE"

 
チェックポイント
このプログラムをBernie様のPocket BASIC Simulator.でプレイする際は、プログラムリストを以下のように変更してください。
[P0]
行番号 説明
1行 SET F2:を削除
変数表
変数 説明
スタート合図用文字データ
A$,B$ プレイヤーパターンデータ…A$(0)〜A$(1)
C$,D$,E$,F$,G$ 風船パターンデータ…C$(0)〜C$(4)
キー入力用フラグ
I,J ループ用(汎用)
K$ 入力キー取得用
風船パターン取得用
フライングカウンタ
スタート合図時間
自己タイム(表記→QT:クオリファイタイム)
レコードタイム(表記→RT)
プレイヤーパターン取得用
空気注入カウンタ
スタート合図表示用
プログラムマップ
[P0] メインルーチン(253step)
行番号 説明
初期設定
最優秀記録、記録保持者表示/スタート処理
3〜6 競技中処理(画面表示、キー入力、タイム測定等)
7〜10 競技後処理(記録判定、レコードタイム更新処理等)
[P1] サブルーチン#1(25step)
行番号 説明
メイン画面描画
[P2] サブルーチン#2(158step)
行番号 説明
1〜4 スタート合図表示、フライング判定処理
5〜7 フライング、競技失格処理
[P3] サブルーチン#3(15step)
行番号 説明
表示ウェイト処理
[P9] イニシャライズ(86step ※注釈行含まず)
行番号 説明
1〜2 初期設定
3〜5 注釈行※この行以降は無視
 
特殊キャラクタ一覧
プログラムリスト内で使用している特殊キャラクタのエスケープシーケンスは下記の通りです。
Bernie様のPocket BASIC Simulator.でプレイする際は、お手数ですが手動で変換してください。
キャラクタパターン エスケープシーケンス
Ω ¥OM

COMMENT







   

PAGE TOP