The Cheating!

The Cheating!(ザ・チーティング)

Introduction

テストでカンニングをして、赤点を免れるゲームです。
増設RAM(OR-1/E)なしのPB-100シリーズで遊べます。


※このゲームはカンニングを奨励するものではありません。カンニングは不正行為です。
公平な試験に反するため、発覚した場合は厳しい処罰が下りますので、絶対におやめください。

 
スクリーンショット
RUN DEG
Π Ω Π
<実行画面1>ゲーム画面
RUN DEG
Π Ω
<実行画面2>カンニング成功
RUN DEG STOP
<実行画面3>カンニング失敗

 

Game Story and System

ゲーム内容
あなたは、テストで赤点(29点)を免れるため、カンニングすることを思いつきました。
先生に見つからないようにして、両隣の席の人の答案を覗き見してください。
制限時間は60秒です。
カンニングが成功すると1回につき点数5点を獲得できますが、先生に見つかってしまうとゲームオーバーです。
無事、赤点以上の成績を修められれば、何事もなかったように次のテストに進めます。
なお、テスト中は点数を10点取るごとに難易度があがります。


※このゲームはカンニングを奨励するものではありません。カンニングは不正行為です。
公平な試験に反するため、発覚した場合は厳しい処罰が下りますので、絶対におやめください。

 

Characters

登場キャラクタ
キャラクタパターン 説明
Ω 勉強嫌いの男の子
本編の主人公
先生
π 秀才くんの席(机)
必ず模範解答が得られます
 

Operation Guide

基本操作説明
4
左の席の答案を覗く
6
右の席の答案を覗く
EXE
画面送り、決定
 

Program Execution

プログラムの入力
The Cheating! for PB-100のプログラムを入力する前に、下記の操作を実行してください。
実行後、プログラムリストをよく見て、間違いのないように入力してください。

 
MODE 1
プログラム入力モード(WRT)に切り替え
Shift 0
プログラムエリア[P0]に切り替え
CLEAR A EXE
メモリ内に書き込まれている全てのプログラムを消去
DEFM 0 EXE
メモリ(変数)を設定
プログラムの実行
The Cheating! for PB-100のプログラムの入力後、下記の操作を実行するとゲームスタートです。
 
MODE 0
プログラム実行モード(RUN)に切り替え
Shift 0
指定されたプログラムエリア[P0]のプログラムを実行
 

Technical Documentation

Program List for PB-100
The Cheating!のプログラムリスト
※上記プログラムリストは、マウスの右クリックで“名前を付けて画像を保存”すると、原寸大(570×301pixel)で見ることが出来ます。
Program List for PB-SIM

[P0]
10 VAC:R=1
20 D=1:S=0:T=59:Q=29:W=6
30 PRINT "TEST";R,"¥SP<HAJIME!"
40 PRINT CSR 0;" ¥PI ¥OM ¥PI :";T;" ";:B=INT (RAN#*2)+1:C=0
50 IF B=1;X=0
60 IF B=2;X=6
70 FOR I=0 TO W
80 PRINT CSR X;"¥SP";
90 IF KEY="4";C=1:IF B<>C;PRINT CSR 1;"¥CI¥LA";:GOTO 200
100 IF KEY="6";C=2:IF B<>C;PRINT CSR 4;"¥RA¥CI";:GOTO 200
110 IF B=C THEN 180
120 NEXT I
130 T=T-1:IF T=0 THEN 150
140 GOTO 40
150 PRINT :PRINT "¥SP<SOKOMADE!"
160 IF Q<>0;PRINT "o(¥CS ¥CS;)o NG!","GAME OVER!":GOSUB 240:GOTO 10
170 PRINT "d(*'-')b OK!","GOOD JOB!":GOSUB 240:R=R+1:GOTO 20
180 IF C=1;PRINT CSR 1;"<KORA!":GOTO 160
190 PRINT CSR 0;"KORA!>":GOTO 160
200 S=S+5:Q=Q-5:IF Q<0;Q=0
210 IF S=10*D;W=W-.5:D=D+1:IF W<1;W=1
220 IF S>100;S=100:GOTO 150
230 GOTO 130
240 PRINT "SCORE";S:RETURN
250 REM "TheCheating!"
260 REM "  2012/04/29"
270 REM "  AUTHOR:HIE"

 
変数表
変数 説明
B,C 判定用
D,W 難易度調整用
ループ用(汎用)
ノルマ(赤点)
ラウンド
スコア
制限時間
先生座標
 
プログラムマップ
[P0] メインルーチン(493step ※注釈行含めず)
行番号 説明
10〜20 初期設定
30 ラウンド表示
40 画面設定
50〜80 先生表示設定
90〜140 キー入力、覗き見、制限時間判定
150〜170 テスト終了、赤点判定、ゲームオーバー処理
180〜190 カンニング失敗処理
200〜230 カンニング成功処理
240 テスト結果(得点)表示
250〜270 注釈行※この行以降は無視
 
特殊キャラクタ一覧
プログラムリスト内で使用している特殊キャラクタのエスケープシーケンスは下記の通りです。
Bernie様のPocket BASIC Simulator.でプレイする際は、お手数ですが手動で変換してください。
キャラクタパターン エスケープシーケンス
¥SP
π ¥PI
Ω ¥OM
¥CI
¥LA
¥RA
_ ¥CS

 

COMMENT







   

PAGE TOP